* UNITIND.SHA. SHAZAM FILE FOR INDEX SERIES
* RUN BY: "file input path+unitind.sha", for example: file input s:\unit_root\input\unitind.sha
*         Change the path to where you have your SHAZAM control files and data. Keep your work clean
*         by directing program output to a separate subdirectory.
=?SET NOWIDE NOCC
=?FILE OUTPUT s:\unit_root\output\unitind.out
* MEMORY IS INCREASED TO 1500 KB AND COMMAND ROW LENGTH TO 250
     PAR 1500
     SET COMLEN=250
* READING DATA & TRANSFORMING TO LOGS
=?     READ (s:\unit_root\input\globeind.dat) &
             DATE USA GER HKG GBR MEX FRA SIN AUS JPN CAN SWI FIN SWE NOR DEN
=?     FILE 11 s:\unit_root\output\dfglsind.out
=?     SAMPLE 1 753
=? GENR LNUSA = LOG(USA)
=? GENR LNFIN = LOG(FIN)
=? GENR LNSWE = LOG(SWE)
*
* Unit Root tests for logarithmic index series
*
COINT LNUSA LNFIN LNSWE
COINT LNUSA LNFIN LNSWE/TYPE=PP
*
* The DF-GLS test
*
=SET NOECHO
=PROC DFGLS
=SET NODOECHO NOOUTPUT
SAMPLE FIRST LAST
GENR z0 = 1
GENR z = TIME(FIRST-1)
GEN1 T = LAST-FIRST+1
GEN1 c = -13.5
GEN1 alpha = 1 + c/T
IF(z.EQ.1) z0_tilde = z0
IF(z.GT.1) z0_tilde = z0 - alpha*LAG(z0)
IF(z.EQ.1) z_tilde = z
IF(z.GT.1) z_tilde = z - alpha*LAG(z)
IF(z.EQ.1) y_tilde = y
IF(z.GT.1) y_tilde = y - alpha*LAG(y)
OLS y_tilde z0_tilde z_tilde/COEFF=Beta
GEN1 B0 = Beta(1)
GEN1 B1 = Beta(2)
GENR y_tau = y - z0*B0 - z*B1
GEN1 FIRST4 = FIRST+4
SAMPLE FIRST4 LAST
GENR y_tau_1 = LAG(y_tau)
GENR yvar = y_tau - y_tau_1
GENR y_diff1 = LAG(y_tau) - LAG(y_tau,2)
GENR y_diff2 = LAG(y_tau,2) - LAG(y_tau,3)
GENR y_diff3 = LAG(y_tau,3) - LAG(y_tau,4)
OLS yvar y_tau_1 y_diff1/NOCONST/COEFF=Beta1/STDERR=StdE1/TRATIO=TRatio1
FORMAT(1X,5F14.6)
WRITE(11) Beta1/FORMAT/WIDE
WRITE(11) StdE1/FORMAT/WIDE
WRITE(11) TRatio1/FORMAT/WIDE
WRITE(11) 
OLS yvar y_tau_1 y_diff1 y_diff2/NOCONST/COEFF=Beta2/STDERR=StdE2/TRATIO=TRatio2
WRITE(11) Beta2/FORMAT/WIDE
WRITE(11) StdE2/FORMAT/WIDE
WRITE(11) TRatio2/FORMAT/WIDE
WRITE(11) 
OLS yvar y_tau_1 y_diff1 y_diff2 y_diff3/NOCONST/COEFF=Beta3/STDERR=StdE3/TRATIO=TRatio3
WRITE(11) Beta3/FORMAT/WIDE
WRITE(11) StdE3/FORMAT/WIDE
WRITE(11) TRatio3/FORMAT/WIDE
WRITE(11) 
SAMPLE FIRST LAST
SET DOECHO
=PROCEND
=SET ECHO
*
* DF-GSL Unit Root tests for logarithmic index series
*
=?GEN1 FIRST = 1
=?GEN1 LAST = 752
=?SAMPLE FIRST LAST
*
* USA
*
=?GENR y = LNUSA
=?EXEC DFGLS
*
* Finland
*
=?GENR y = LNFIN
=?EXEC DFGLS
*
* Sweden
*
=?GENR y = LNSWE
=?EXEC DFGLS
END
STOP